How to get browser time zone using Flex / AS3?

Question

How to get client browser timezone in Flex / AS3?

Answer 1

Take a look at the following: http://thanksmister.com/2011/10/06/determining-local-timezone-in-actionscript-air-flex-as3/

This can help.

Answer 2

Can you use the timeZoneOffest of a Date object?

Honestly, I believe that this simply conveys information based on the settings of the user OS. I would not expect bBrowser to really have a timezone.

Answer 3

I wanted to get the same, but did not find anything on the Internet. I already used FlexDateUtils ( blog post ), but it only formats timezones as "GMT -600". Fortunately, I can confidently say that the users of my application will be in the United States, so I changed to "DateUtils.buildTimeZoneDesignation (date: Date)" as follows. Hope this helps.

    private static function buildTimeZoneDesignation( date:Date ):String {
        if ( !date ) {
            return "";
        }
        var timezoneOffsetHours:Number = date.getTimezoneOffset() / 60;

        // custom timezone handlers (assumes major U.S. zones with daylight savings time dates as of 2011)
        if (3 < timezoneOffsetHours && timezoneOffsetHours < 12)
        {
            var usDST:Boolean = false;
            // the date of the Sunday before today unless today is Sunday
            var sundayBeforeToday:Number = date.date - date.day;
            if (2007 <= date.fullYear) {
                // test for since-2007 extended daylight savings time
                if (2 < date.month && date.month < 10) {
                    // daylight savings time (April through October)
                    usDST = true;
                }
                else if (date.month == 2) {
                    // DST starts second Sunday in March
                    usDST = (7 < sundayBeforeToday);
                }
                else if (date.month == 10) {
                    // DST ends first Sunday in November
                    usDST = (0 < sundayBeforeToday);
                }
            }
            else {
                // test for pre-2007 daylight savings time
                if (3 < date.month && date.month < 9) {
                    // daylight savings time (May through September)
                    usDST = true;
                }
                else if (date.month == 3) {
                    // DST starts first Sunday in April
                    usDST = (0 < sundayBeforeToday);
                }
                else if (date.month == 9) {
                    // DST ends last Sunday in October
                    usDST = (sundayBeforeToday + 7 <= 31);
                }
            }
            // return custom timezone strings for US timezones
            switch (timezoneOffsetHours) {
                case 4:
                    // Eastern or Atlantic
                    return usDST ? "EDT" : "AST";
                case 5:
                    // Central or Eastern
                    return usDST ? "CDT" : "EST";
                case 6:
                    // Mountain or Central
                    return usDST ? "MDT" : "CST";
                case 7:
                    // Pacific or Mountain
                    return usDST ? "PDT" : "MST";
                case 8:
                    // Alaska or Pacific
                    return usDST ? "AKDT" : "PST";
                case 9:
                    // Hawaii or Alaska
                    return usDST ? "HADT" : "AKST";
                case 10:
                    // Samoa or Hawaii
                    return usDST ? "SDT" : "HAST";
                case 11:
                    if (!usDST)
                        // Samoa
                        return "SST";
                    break;
            }
        }

        // else just generate a GMT string

        var timeZoneAsString:String = "GMT ";
        // timezoneoffset is the number that needs to be added to the local time to get to GMT, so
        // a positive number would actually be GMT -X hours
        if ( 0 < timezoneOffsetHours && timezoneOffsetHours < 10 ) {
            timeZoneAsString += "-0" + ( timezoneOffsetHours ).toString();
        } else if ( date.getTimezoneOffset() < 0 && timezoneOffsetHours > -10 ) {
            timeZoneAsString += "0" + ( -1 * timezoneOffsetHours ).toString();
        }
        // add zeros to match standard format
        timeZoneAsString += "00";

        return timeZoneAsString;
    }