All geek questions in one place

Use the xslt replace function to replace a word with an element

I want to use the XSLT replace function to replace words in text with

<strong>word</strong>.

I wrote the following template:

<xsl:template name="make-bold">
  <xsl:param name="text"/>
  <xsl:param name="word"/>
  <xsl:variable name="replacement">
     <strong><xsl:value-of select="$word"/></strong>
  </xsl:variable>
  <xsl:value-of select="replace($text, $word,  $replacement )" />
</xsl:template>

Unfortunately, they are not displayed, but everything else works.

Can anyone help me?

Best, Suidu

+3
source share
2 answers

Well, the replacement function http://www.w3.org/TR/xpath-functions/#func-replace takes a string and returns a string. It seems you want to create a node element, not a simple string. In this case, using the analytic line http://www.w3.org/TR/xslt20/#analyze-string instead of replacing can help.

Here is an example XSLT 2.0 style sheet:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs"
  version="2.0">

  <xsl:output method="html" indent="no"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@*, node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="p">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates select="text()" mode="wrap">
        <xsl:with-param name="words" as="xs:string+" select="('foo', 'bar')"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="text()" mode="wrap">
    <xsl:param name="words" as="xs:string+"/>
    <xsl:param name="wrapper-name" as="xs:string" select="'strong'"/>
    <xsl:analyze-string select="." regex="{string-join($words, '|')}">
      <xsl:matching-substring>
        <xsl:element name="{$wrapper-name}">
          <xsl:value-of select="."/>
        </xsl:element>
      </xsl:matching-substring>
      <xsl:non-matching-substring>
        <xsl:value-of select="."/>
      </xsl:non-matching-substring>
    </xsl:analyze-string>
  </xsl:template>

</xsl:stylesheet>

XSLT 2.0, Saxon 9,

<html>
  <body>
    <p>This is an example with foo and bar words.</p>
  </body>
</html>

:

<html>
  <body>
    <p>This is an example with <strong>foo</strong> and <strong>bar</strong> words.</p>
  </body>
</html>
+3

hmm is, , node?

, xslt 2.0, , ..

<xsl:template match="yourtextelement">
   <xsl:call-template name="MaketextStrong">
</xsl:template>

<xsl:template name="MaketextStrong">
   <xsl:param name="text" select="."/>
   <xsl:choose>
   <xsl:when test="contains($text, 'texttomakestrong')">
      <xsl:value-of select="substring-before($text, 'texttomakestrong')"/>
      <strong>texttomakestrong</strong>
      <xsl:call-template name="break">
          <xsl:with-param name="text" select="substring-after($text,
'texttomakestrong')"/>
      </xsl:call-template>
   </xsl:when>
   <xsl:otherwise>
 <xsl:value-of select="$text"/>
   </xsl:otherwise>
   </xsl:choose>
</xsl:template>
0

Source: https://habr.com/ru/post/1779578/

More articles:


All Articles