Rijndael drove: breaking off long text

Question

I spent some time exploring the use of the RijndaelManaged library in .NET and developed the following function to check text encryption with minor changes to the MSDN library:

Function encryptBytesToBytes_AES(ByVal plainText As Byte(), ByVal Key() As Byte, ByVal IV() As Byte) As Byte()
        ' Check arguments.
        If plainText Is Nothing OrElse plainText.Length <= 0 Then
            Throw New ArgumentNullException("plainText")
        End If
        If Key Is Nothing OrElse Key.Length <= 0 Then
            Throw New ArgumentNullException("Key")
        End If
        If IV Is Nothing OrElse IV.Length <= 0 Then
            Throw New ArgumentNullException("IV")
        End If

        ' Declare the RijndaelManaged object
        ' used to encrypt the data.
        Dim aesAlg As RijndaelManaged = Nothing

        ' Declare the stream used to encrypt to an in memory
        ' array of bytes.
        Dim msEncrypt As MemoryStream = Nothing

        Try
            ' Create a RijndaelManaged object
            ' with the specified key and IV.
            aesAlg = New RijndaelManaged()
            aesAlg.BlockSize = 128
            aesAlg.KeySize = 128
            aesAlg.Mode = CipherMode.ECB
            aesAlg.Padding = PaddingMode.None
            aesAlg.Key = Key
            aesAlg.IV = IV

                ' Create a decrytor to perform the stream transform.
                Dim encryptor As ICryptoTransform = aesAlg.CreateEncryptor(aesAlg.Key, aesAlg.IV)

                ' Create the streams used for encryption.
                msEncrypt = New MemoryStream()
                Using csEncrypt As New CryptoStream(msEncrypt, encryptor, CryptoStreamMode.Write)
                    Using swEncrypt As New StreamWriter(csEncrypt)

                        'Write all data to the stream.
                        swEncrypt.Write(plainText)
                    End Using
                End Using

        Finally
            ' Clear the RijndaelManaged object.
            If Not (aesAlg Is Nothing) Then
                aesAlg.Clear()
            End If
        End Try
        ' Return the encrypted bytes from the memory stream.
        Return msEncrypt.ToArray()

    End Function

Here is the actual code that I call encryptBytesToBytes_AES () with:

Private Sub btnEncrypt_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnEncrypt.Click
    Dim bZeroKey As Byte() = {&H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0, &H0}
    PrintBytesToRTF(encryptBytesToBytes_AES(bZeroKey, bZeroKey, bZeroKey))
End Sub

However, I get an exception on swEncrypt.Write(plainText)which states that the data length for encryption is not valid.

However, I know that the size of my key, iv, and plaintext is 16 bytes == 128 bits == aesAlg.BlockSize. Why does this throw this exception? Is it because StreamWriter is trying to create a String (supposedly with some encoding) and it doesn't like & H0 as a value?

---

EDIT: , , StreamWriter. Gander MSDN , - , . ?

Answer 1

StreamWriter.
StreamWriter Byte() .

:

Function encryptBytesToBytes_AES(ByVal plainText As Byte(), ByVal Key() As Byte, ByVal IV() As Byte) As Byte()
    ' Check arguments.'
    If plainText Is Nothing OrElse plainText.Length <= 0 Then
        Throw New ArgumentNullException("plainText")
    End If
    If Key Is Nothing OrElse Key.Length <= 0 Then
        Throw New ArgumentNullException("Key")
    End If
    If IV Is Nothing OrElse IV.Length <= 0 Then
        Throw New ArgumentNullException("IV")
    End If

    ' Declare the RijndaelManaged object'
    ' used to encrypt the data.'
    Dim aesAlg As RijndaelManaged = Nothing

    Dim encryptedData As Byte()

    Try
        ' Create a RijndaelManaged object'
        ' with the specified key and IV.'
        aesAlg = New RijndaelManaged()
        aesAlg.BlockSize = 128
        aesAlg.KeySize = 128
        aesAlg.Mode = CipherMode.ECB
        aesAlg.Padding = PaddingMode.None
        aesAlg.Key = Key
        aesAlg.IV = IV

        ' Create a decrytor to perform the stream transform.'
        Dim encryptor As ICryptoTransform = aesAlg.CreateEncryptor()

        ' Create the streams used for encryption.'
        Using msEncrypt As New MemoryStream()

            Using csEncrypt As New CryptoStream(msEncrypt, encryptor, CryptoStreamMode.Write)
                csEncrypt.Write(plainText, 0, plainText.Length)
                csEncrypt.FlushFinalBlock()
            End Using
            encryptedData = msEncrypt.ToArray()
        End Using

    Finally
        ' Clear the RijndaelManaged object.'
        If Not (aesAlg Is Nothing) Then
            aesAlg.Clear()
        End If
    End Try
    ' Return the encrypted bytes from the memory stream.'
    Return encryptedData
End Function