How can I read a random string from notecard in LSL?

Question

I have a notebook with a different word on each line, and I would like to be able to select from lines randomly. How can i do this?

Answer 1

First, as you already mentioned, you need notecard. In this example, I use one of the named “colors” with the following contents:

red
blue
green
yellow
orange
purple

With this record, the following script will read and share a random line from the card every time you touch it.

//this script will grab and chat a random line from the "colors" notecard each time the prim is touched.

string card = "colors";
key linecountid;
key lineid;
integer linemax;

integer random_integer( integer min, integer max )
{
  return min + (integer)( llFrand( max - min + 1 ) );
}


default
{
    state_entry()
    {
        //get the number of notecard lines
        linecountid = llGetNumberOfNotecardLines(card);
    }

    touch_start(integer total_number)
    {
        lineid = llGetNotecardLine(card, random_integer(0, linemax));
    }

    dataserver(key id, string data)
    {
        if (id == linecountid)
        {
            linemax = (integer)data - 1;
        }
        else if (id == lineid)
        {
            llSay(0, data);
        }
    }
}

Answer 2

, ​​ , , . , , llFrand, ( , ):

integer max;
integer random = llFrand((integer)(max/2)) + llFrand((integer)(max/2));

, CHANGED_INVENTORY, , . , , , ? , ? notecard? .

NOTECARD colors , script:

blue
red
green
yellow
black

SCRIPT :

//  this script reads from a notecard which is named whatever you set in init
//  in this example from a notecard named "colors"

string ncName;
key ncNumOfLinesReqId;
key ncReqId;
integer numOfLines;

init()
{
//  Put the name of your notecard as in the prim inventory here.
    ncName = "colors";
}

default
{
    changed(integer change)
    {
//      reset script to make sure you have the current number of lines
//      CHANGED_OWNER has the integer value 0x80 (128)
//      CHANGED_INVENTORY has the integer value 0x01 (1)
        if (change & (CHANGED_OWNER | CHANGED_INVENTORY))
        {
            llResetScript();
        }
    }

    state_entry()
    {
        init();

//      get the number of notecard lines
        ncNumOfLinesReqId = llGetNumberOfNotecardLines(ncName);
    }

    touch_start(integer num_detected)
    {
//      if the number of lines is 0
        if (!numOfLines)
        {
//          PUBLIC_CHANNEL has the integer value 0
            llSay(PUBLIC_CHANNEL, "~!~ Unconfigured, check notecard ~!~");
        }
        else // if number of lines not 0
        {
            ncReqId = llGetNotecardLine(ncName, (integer)llFrand(numOfLines));
        }
    }

    dataserver(key reqId, string data)
    {
        if (reqId == ncNumOfLinesReqId)
        {
//          make sure you typecast!
            numOfLines = (integer)data;
        }
        else if (reqId == ncReqId)
        {
//          PUBLIC_CHANNEL has the integer value 0
            llSay(PUBLIC_CHANNEL, data);
        }
    }
}

:

, , . UUID , , ( ). , , UUID. , - .

- Second Life.