How to get a list of duplicate values ​​in a range

Question

I tried to write macros, but using copy and paste, but I prefer the codes to be dynamic as the range of my data changes weekly.

I have 2 columns, Aand D. The column Ais a pivot table, so I think it's possible that why the VBAcodes to move down the lines don't work. (error while trying to move pivot table). I want the column to Dbe a list of unique duplicates that are in the column A, and condense it so that there are no spaces.

So far I can extract unique duplicates and condense them, but the results are inserted from D1 instead of D8 . So I need help to reduce the values ​​of 8 rows. Now I do not want to copy and paste the pivot table as values ​​or try to get rid of it, since I need a pivot table, since I can update it every week for a new list.

Any suggestion or advice is appreciated.

    Sub dp()

    AR = Cells(Rows.Count, "A").End(xlUp).Row

    For Each p1 In Range(Cells(8, 1), Cells(AR, 1))
        For Each p2 In Range(Cells(8, 1), Cells(AR, 1))
            If p1 = p2 And Not p1.Row = p2.Row Then
                Cells(p1.Row, 4) = Cells(p1.Row, 1)
                Cells(p2.Row, 4) = Cells(p2.Row, 1)
            End If
        Next p2
    Next p1
    Columns(4).RemoveDuplicates Columns:=Array(1)
        Dim lastrow As Long
        Dim i As Long
        lastrow = Range("D:D").End(xlDown).Row

        For i = lastrow To 1 Step -1

        If IsEmpty(Cells(i, "D").Value2) Then

            Cells(i, "D").Delete shift:=xlShiftUp
        End If
    Next i
End Sub

Answer 1

another approach here

Sub dp2()
    Dim n&, c As Range, rng As Range, Dic As Object
    Set Dic = CreateObject("Scripting.Dictionary")
    Dic.comparemode = vbTextCompare
    Set rng = Range("A8:A" & Cells(Rows.Count, "A").End(xlUp).Row)
    n = 8
    For Each c In rng
        If Dic.exists(c.Value2) And Dic(c.Value2) = 0 Then
            Dic(c.Value2) = 1
            Cells(n, "D").Value2 = c.Value2
            n = n + 1
        ElseIf Not Dic.exists(c.Value2) Then
            Dic.Add c.Value2, 0
        End If
    Next c
End Sub

, :
1) : Columns(4).RemoveDuplicates Columns:=Array(1)
: Range("D8:D" & Cells(Rows.Count, "D").End(xlUp).Row).RemoveDuplicates Columns:=1
2) : lastrow = Range("D:D").End(xlDown).Row
# 8 , , : lastrow = Cells(Rows.Count, "D").End(xlUp).Row

3), to 1 step -1 to 8 step -1

, , :

Sub dp()
    Dim AR As Long, p1 As Range, p2 As Range, lastrow&, i&
    AR = Cells(Rows.Count, "A").End(xlUp).Row
    For Each p1 In Range(Cells(8, 1), Cells(AR, 1))
        For Each p2 In Range(Cells(8, 1), Cells(AR, 1))
            If p1 = p2 And Not p1.Row = p2.Row Then
                Cells(p1.Row, 4) = Cells(p1.Row, 1)
                Cells(p2.Row, 4) = Cells(p2.Row, 1)
            End If
    Next p2, p1
    Range("D8:D" & Cells(Rows.Count, "D").End(xlUp).Row).RemoveDuplicates Columns:=1
    lastrow = Cells(Rows.Count, "D").End(xlUp).Row
    For i = lastrow To 8 Step -1
        If IsEmpty(Cells(i, "D").Value2) Then
            Cells(i, "D").Delete shift:=xlShiftUp
        End If
    Next i
End Sub

Answer 2

Sub dp()

Dim AR As Long, p1 As Range, n As Long

AR = Cells(Rows.Count, "A").End(xlUp).Row
n = 8
With Range(Cells(8, 1), Cells(AR, 1))
    For Each p1 In .Cells
        If WorksheetFunction.CountIf(.Cells, p1) > 1 Then
            If WorksheetFunction.CountIf(Columns(4), p1) = 0 Then
                Cells(n, "D") = p1
                n = n + 1
            End If
        End If
    Next p1
End With

End Sub

Answer 3

:

• ArraysList
• ADODB.Recordset
• CountIf

---

ArraysList

Sub ListDuplicates()
    Dim v, listValues, listDups
    Set listValues = CreateObject("System.Collections.ArrayList")
    Set listDups = CreateObject("System.Collections.ArrayList")

    For Each v In Range("A8", Cells(Rows.Count, "A").End(xlUp)).Value
        If listValues.Contains(v) And Not listDups.Contains(v) Then listDups.Add v
        listValues.Add v
    Next

    Range("D8").Resize(listDups.Count).Value = Application.Transpose(listDups.ToArray)
End Sub

ADODB.Recordset

Sub QueryDuplicates()
    Dim rs As Object, s As String
    Set rs = CreateObject("ADODB.Recordset")
    s = ActiveSheet.Name & "$" & Range("A7", Cells(Rows.Count, "A").End(xlUp)).Address(False, False)
    rs.Open "SELECT [Pivot Table] FROM [" & s & "] GROUP BY [Pivot Table] HAVING COUNT([Pivot Table]) > 1", _
            "Provider=MSDASQL;DSN=Excel Files;DBQ=" & ThisWorkbook.FullName

    If Not rs.EOF Then Range("D8").CopyFromRecordset rs
    rs.Close
    Set rs = Nothing
End Sub

Array CountIf ( SJR, )

Sub ListDuplicatesArray()
    Dim v, vDups
    Dim x As Long, y As Long
    ReDim vDups(x)
    With Range("A8", Cells(Rows.Count, "A").End(xlUp))

        For Each v In .Value
            If WorksheetFunction.CountIf(.Cells, v) > 1 Then
                For y = 0 To UBound(vDups)
                    If vDups(y) = v Then Exit For
                Next
                If y = UBound(vDups) + 1 Then
                    ReDim Preserve vDups(x)
                    vDups(x) = v
                    x = x + 1
                End If

            End If
        Next
    End With

    Range("D8").Resize(UBound(vDups) + 1).Value = Application.Transpose(vDups)
End Sub

Answer 4

:

Option Explicit

Sub main()
    Dim vals As Variant, val As Variant
    Dim strng As String

    With Range(Cells(8, 1), Cells(Rows.count, 1).End(xlUp))
        vals = Application.Transpose(.Value)
        strng = "|" & Join(vals, "|") & "|"
        With .Offset(, 3)
            .Value = Application.Transpose(vals)
            .RemoveDuplicates Columns:=1, Header:=xlNo
            For Each val In .SpecialCells(xlCellTypeConstants)
                strng = Replace(strng, val, "", , 1)
            Next val
            vals = Split(WorksheetFunction.Trim(Replace(strng, "|", " ")), " ")
            With .Resize(UBound(vals) + 1)
                .Value = Application.Transpose(vals)
                .RemoveDuplicates Columns:=1, Header:=xlNo
            End With
        End With
    End With
End Sub