All geek questions in one place

How do we identify a set of nodes and add this set to another, where does the structure of the XML source change in XSLT?

I am trying to convert Flash based text format to HTML based text.

There are blocks <LI></LI>in the original xml, I need to add a neighboring block <LI>inside the block <ul>.

<p></p>
<li></li> ------
<li></li>      | - should be wrapped with <ul> tag
<li></li> ------
<p></p>
<li></li>
<li></li>
<li></li>
<p></p>

XML source

<root>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="LEFT">
            edfg
        </P>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="LEFT">
            sdgfdsgsds
        </P>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            sdfgdsg
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            dsgdfgdsfg
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            <FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">errytrtyr</FONT>
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="LEFT">
            sdgfdsgsds
        </P>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            <FONT FACE="System" SIZE="16" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">nm,hjku
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            <FONT FACE="System" SIZE="16" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">
                <B>hgjgj</B>
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="CENTER">
            <FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">centered text</FONT>
        </P>
    </TEXTFORMAT>
</root>

Expected Result

<div>
    <div style="text-align:LEFT; ">
        edfg
    </div>
    <div style="text-align:LEFT; ">
        sdgfdsgsds
    </div>
    <ul>
        <li>
            sdfgdsg
        </li>
        <li>
            dsgdfgdsfg
        </li>
        <li>
            <FONT COLOR="#4B4B4B" FACE="Lato" SIZE="12">errytrtyr</FONT>
        </li>
    </ul>
    <div style="text-align:LEFT; ">
        sdgfdsgsds
    </div>
    <ul>
        <li>
            <FONT COLOR="#4B4B4B" FACE="System" SIZE="16">nm,hjku
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </li>
        <li>
            <FONT COLOR="#4B4B4B" FACE="System" SIZE="16">
                <B>hgjgj</B>
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </li>
    </ul>
    <div style="text-align:CENTER; ">
        <FONT COLOR="#4B4B4B" FACE="Lato" SIZE="12">centered text</FONT>
    </div>
</div>

My code is:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes" method="html"/>

    <!-- identity template -->

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="root">
        <div>
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <!-- remove unwanted attributes -->
    <xsl:template match="@LETTERSPACING|@KERNING"/>

    <!-- Remove <P> tag and set the alignment -->
    <xsl:template match="P">
        <div>
            <xsl:attribute name="style">
                <!-- collect attributes -->
                <xsl:variable name="styles">
                    <xsl:if test="@ALIGN">
                        <xsl:value-of select="concat('text-align:', @ALIGN )"/>
                        <xsl:text>; </xsl:text>
                    </xsl:if>
                </xsl:variable>
                <!-- delete trailing spaces -->
                <xsl:value-of select="$styles"/>
            </xsl:attribute>
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <!-- Replace <LI> with <li> -->
    <xsl:template match="LI">
        <li><xsl:apply-templates/></li>
    </xsl:template>

    <!-- Remove TEXTFORMAT -->
    <xsl:template match="TEXTFORMAT">
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>
+4
source share
2 answers

The following XSLT 1.0 conversion gives you what seems like the desired result:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes" method="html"/>

    <xsl:key name="list" match="TEXTFORMAT[LI]" use="generate-id(
        (self::*|preceding-sibling::*)[LI][
            not(preceding-sibling::*[1][LI])
        ][last()]
    )" />

    <!-- identity template -->
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="root">
        <div>
            <xsl:apply-templates />
        </div>
    </xsl:template>

    <!-- Remove <P> tag and set the alignment -->
    <xsl:template match="P">
        <div>
            <xsl:attribute name="style">
                <xsl:apply-templates select="@*" mode="css" />
            </xsl:attribute>
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="@ALIGN" mode="css">
        <xsl:value-of select="concat('text-align:', ., ';')"/>
    </xsl:template>
    <!-- add more -->
    <xsl:template match="@*" mode="css" />

    <!-- remove unwanted attributes -->
    <xsl:template match="@LETTERSPACING|@KERNING"/>

    <xsl:template match="TEXTFORMAT[LI]">
        <xsl:variable name="adjacent" select="key('list', generate-id())" />
        <xsl:if test="$adjacent">
            <ul>
                <xsl:apply-templates select="$adjacent/LI" />
            </ul>
        </xsl:if>
    </xsl:template>

    <!-- Replace <LI> with <li> -->
    <xsl:template match="LI">
        <li><xsl:apply-templates/></li>
    </xsl:template>

    <!-- Remove TEXTFORMAT -->
    <xsl:template match="TEXTFORMAT">
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

Result:

<div>
   <div style="text-align:LEFT;">
      edfg

   </div>
   <div style="text-align:LEFT;">
      sdgfdsgsds

   </div>
   <ul>
      <li>
         sdfgdsg

      </li>
      <li>
         dsgdfgdsfg

      </li>
      <li><FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B">errytrtyr</FONT></li>
   </ul>
   <div style="text-align:LEFT;">
      sdgfdsgsds

   </div>
   <ul>
      <li><FONT FACE="System" SIZE="16" COLOR="#4B4B4B">nm,hjku
            <FONT FACE="Lato" SIZE="12"></FONT></FONT></li>
      <li><FONT FACE="System" SIZE="16" COLOR="#4B4B4B"><B>hgjgj</B><FONT FACE="Lato" SIZE="12"></FONT></FONT></li>
   </ul>
   <div style="text-align:CENTER;"><FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B">centered text</FONT></div>
</div>

The key to the solution, literally, is this design:

<xsl:key name="list" match="TEXTFORMAT[LI]" use="generate-id(
    (self::*|preceding-sibling::*)[LI][
        not(preceding-sibling::*[1][LI])
    ][last()]
)" />

TEXTFORMAT[LI] TEXTFORMAT[LI], , .. , TEXTFORMAT[LI] .

, <xsl:template match="TEXTFORMAT[LI]">, - TEXTFORMAT[LI].

+1

XSLT 1.0.

, LI P, root , :

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="LI" match="TEXTFORMAT[LI]" use="generate-id(preceding-sibling::TEXTFORMAT[P][1])" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="root">
    <div>
        <xsl:apply-templates select="TEXTFORMAT[P]"/>
    </div>
</xsl:template>

<xsl:template match="TEXTFORMAT">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="P">
    <div style="text-align:{@ALIGN};">
        <xsl:apply-templates/>
    </div>
    <xsl:variable name="li" select="key('LI', generate-id(..))" />
    <xsl:if test="$li">
        <ul>
            <xsl:apply-templates select="$li"/>
        </ul>           
    </xsl:if>
</xsl:template>

<xsl:template match="LI">
    <li>
        <xsl:apply-templates/>
    </li>
</xsl:template>

<xsl:template match="@LETTERSPACING|@KERNING"/>

</xsl:stylesheet>
+1

Source: https://habr.com/ru/post/1652426/

More articles:


All Articles