Gnuplot candlestick red and green

Question

Candlesticks on financial sites, at least those that I saw, fill the candlestick with green if the closure is higher than the open and red if the closure is lower than the open.

If I set the fill style, all the candlesticks are filled with the fill color, is there any way in gnuplot 4.6 to use the color scheme, as I described above?

Sample script:

set xdata time
set timefmt"%Y-%m-%d %H:%M:%S"
set xrange ["2014-01-01":"2014-01-02"]
set yrange [*:*]
set datafile separator ","
plot '201401_EURUSD_Hourly.csv' using 1:2:4:3:5 notitle with candlesticks

with some data points

2014-01-01 17:00:00,1.376150,1.376550,1.374020,1.375990
2014-01-01 18:00:00,1.376100,1.377340,1.375980,1.376520 
2014-01-01 19:00:00,1.376440,1.376870,1.375780,1.375860 
2014-01-01 20:00:00,1.375850,1.376470,1.375000,1.376280 
2014-01-01 21:00:00,1.376270,1.376720,1.375970,1.376530 
2014-01-01 22:00:00,1.376550,1.377440,1.376270,1.376530 
2014-01-01 23:00:00,1.376540,1.376540,1.374390,1.374520 
2014-01-02 00:00:00,1.374500,1.375790,1.374380,1.375660 
2014-01-02 01:00:00,1.375630,1.375740,1.374610,1.375000 
2014-01-02 02:00:00,1.374980,1.375270,1.372480,1.373100

Answer 1

Here is an example that uses a predefined color palette to select colors (keyword palette):

set xdata time
set timefmt"%Y-%m-%d %H:%M:%S"
set datafile separator ","

set palette defined (-1 'red', 1 'green')
set cbrange [-1:1]
unset colorbox

set style fill solid noborder

plot '201404_EURUSD_Hourly.csv' using 1:2:4:3:5:($5 < $2 ? -1 : 1)  notitle with candlesticks palette

() -1 (, ) +1 (, ).

4.6.4:

- linecolor rgb variable, rgb-tuple:

set xdata time
set timefmt"%Y-%m-%d %H:%M:%S"
set datafile separator ","

set style fill solid noborder

# Place colored points in 3D at the x,y,z coordinates corresponding to
# their red, green, and blue components
rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)

plot '201404_EURUSD_Hourly.csv' using 1:2:4:3:5:($5 < $2 ? rgb(255,0,0) : rgb(0,255,0))  linecolor rgb variable notitle with candlesticks

, , linecolor variable ( - ):

set xdata time
set timefmt"%Y-%m-%d %H:%M:%S"
set datafile separator ","

set style fill solid noborder

set linetype 1 lc rgb 'red'
set linetype 2 lc rgb 'green'

plot '201404_EURUSD_Hourly.csv' using 1:2:4:3:5:($5 < $2 ? 1 : 2)  linecolor variable notitle with candlesticks